var y r pie g a n mc rw mrs winf;
varexo e_a e_g e_ms e_lam;

parameters sig delta gam rho gampie gamy rhoa rhog bet thetabig eps;

delta=0.36;
bet=0.99;
eps=6;

model(linear);
#theta_p = thetabig/(thetabig+1);
y=y(+1)-sig*(r-pie(+1)+g(+1)-g);
y=a+(1-delta)*n;
mc=rw+n-y;
mrs=(1/sig)*y+gam*n-g;
r=rho*r(-1)+(1-rho)*(gampie*pie+gamy*y)+e_ms;
rw=rw(-1)+winf-pie;
a=rhoa*a(-1)+e_a;
g=rhog*g(-1)+e_g;
pie=bet*pie(+1)+(1-delta)*(1-theta_p*bet)*(1-theta_p)/(theta_p*(1+delta*(eps-1)))*(mc+e_lam);
rw=mrs;
end;

estimated_params;
stderr e_a, uniform_pdf,,,0,1;
stderr e_g, uniform_pdf,,,0,1;
stderr e_ms, uniform_pdf,,,0,1;
stderr e_lam, uniform_pdf,,,0,1;
sig, inv_gamma_pdf, 0.67, 0.9;
gam, normal_pdf, 1, 0.5;
rho, uniform_pdf,,,0,1;
gampie, normal_pdf,1.5 ,0.5;
gamy, normal_pdf,0.125 ,0.125;
rhoa, uniform_pdf,,,0,1;
rhog, uniform_pdf,,,0,1;
thetabig, gamma_pdf, 2, 1.42;
end;

varobs pie r y rw;

estimation(datafile=datarabanal,nobs=75,mh_replic=5000,mh_jscale=0.6,mh_nblocks=1);
//estimation(datafile=datarabanal,nobs=75,mh_replic=20000,mh_jscale=0.6,mode_compute=0,mode_file=rr_mode,load_mh_file);